/*
 * Datalogger Continuous Faludi
 * data is displayed continuously and stored upon request
 * by Rob Faludi www.faludi.com
 */
#define VERSION "1.00"

#include <EEPROM.h>

#define SIZE 511 // number of samples to store (maximum 511)
#define INTERVAL 500  // interval between readings, in milliseconds
#define COUNTDOWN 0 // countdown before beginning, in milliseconds

#define STORE_PIN 2 // momentary switch attached to ground 
#define RETREIVE_PIN 3 //  momentary switch attached to ground 
#define CLEAR_PIN 4 // momentary switch attached to ground
#define LED_PIN 13

unsigned long count=0;
byte data[SIZE];
volatile boolean store = false, retrieve = false;

void setup()
{
  pinMode(STORE_PIN, INPUT);
  pinMode(RETREIVE_PIN, INPUT);
  pinMode(CLEAR_PIN, INPUT);
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(STORE_PIN, HIGH); // enable internal pull-up resistor
  digitalWrite(RETREIVE_PIN, HIGH); // enable internal pull-up resistor
  digitalWrite(CLEAR_PIN, HIGH); // enable internal pull-up resistor

  blinkLED(LED_PIN, 2, 200); // blink the status LED twice
  Serial.begin(9600); // start serial output
  Serial.print("datalogger v");
  Serial.println(VERSION);
  if (SIZE > 511) Serial.println("Error! SIZE cannot be greather than 511!");
  for (int i=0; i<SIZE; i++) data[i] = NULL;  // initialize the data array
  attachInterrupt(0, storeNow, FALLING);  // allow immedate logging of button presses
  attachInterrupt(1, retrieveNow, FALLING);
}


void loop()
{

  // regular readings, starting from zero
  static int count = 0;
  byte reading = analogRead(0)/4;
  if (count < SIZE)  
  {
    data[count] = reading; // save the current reading in an array
  }
  else { // begin rolling data when count exceeds size
    for(int i = 0; i< SIZE; i++) {
      data[i] = data[i+1]; //move the second measurement to be the first one, and so forth until we reach the end of the array.   
    }
    data[SIZE-1] = reading; //save the current reading to the end of the array
  }
  Serial.println(reading,DEC); // print the current reading to the serial port

  count ++;
  delay(INTERVAL);
  
  if (store == true) { // if the store button has been pressed, store the data
  digitalWrite(LED_PIN,HIGH);
    Serial.println("storing");
    for (int i = 0; i<SIZE; i++) {
      EEPROM.write(i, data[i]); // save the array
    }
    store = false; // store data only once per button press
    digitalWrite(LED_PIN,LOW);
  }

  // output readings once each time retrieve switch has been pressed
  if(retrieve == true) {
    digitalWrite(LED_PIN,HIGH);
    Serial.println("retrieving");
    EEPROM.write(0,1); // note that retrieve was requested
    for (int i=1; i<SIZE; i++) {
      Serial.print(EEPROM.read(i),DEC);
      if (i < SIZE-1) Serial.print(","); // comma separated values
      // if (i < SIZE-1) Serial.print("\t"); // tab separated values
    }
    Serial.println("");
    retrieve = false; // retrieve data only once per button press
    digitalWrite(LED_PIN,LOW);
  }

  if (digitalRead(CLEAR_PIN) == LOW) {
    digitalWrite(LED_PIN,HIGH);
    Serial.println("resetting");
    for (int i=0; i<SIZE; i++) data[i] = NULL;  // initialize the data array
    for (int i = 0; i<512; i++) {
      EEPROM.write(i,NULL); // initialize the EEPROM storage
    }
    count = 0;
    digitalWrite(LED_PIN,LOW);
  }
}


// this function blinks the an LED light as many times as requested, at the requested blinking rate
void blinkLED(byte targetPin, int numBlinks, int blinkRate) {
  for (int i=0; i<numBlinks; i++) {
    digitalWrite(targetPin, HIGH);   // sets the LED on
    delay(blinkRate);                     // waits for blinkRate milliseconds
    digitalWrite(targetPin, LOW);    // sets the LED off
    delay(blinkRate);
  }
}


// this function is called when the store button is pressed
void storeNow() {
  store = true;  
}

// this function is called when the retrieve button is pressed
void retrieveNow() {
  retrieve = true;  
}