/*
 * This is sample code for the "Espionage" project in Networked Objects
 * http://www.faludi.com/teaching/networked-objects/assignments/
 * by Rob Faludi http://faludi.com
 * 
 */

#define NAME "Espionage Sample Code"
#define VERSION "1.00"

// software serial
#include <SoftwareSerial.h>
#define RX_PIN 2
#define TX_PIN 3
SoftwareSerial softSerial =  SoftwareSerial(RX_PIN, TX_PIN);

#define LED_PIN 13

// status definitions
#define GET 0
#define READ 1
#define COMBINE 2
#define ANNOUNCE 3
#define SEND 4
#define DONE 5


#define MESSAGE "What hath God wrought?" // YOUR PART OF THE MESSAGE GOES HERE 
#define BUFFER_SIZE 255 // maximum length of the entire message being transmitted
char buffer[BUFFER_SIZE]; // create a character array for storing incoming strings
int idx = 0; // an index variable to put characters into the proper place in the buffer
int status = 0; // keeps track of what mode we're currently in


void setup() {
  pinMode(RX_PIN,INPUT);
  pinMode(TX_PIN,OUTPUT);
  softSerial.begin(9600);
  pinMode(LED_PIN,OUTPUT);
  blinkLED(LED_PIN,2,100);
  Serial.begin(9600);
  Serial.print(NAME);
  Serial.print(" v");
  Serial.print(VERSION);
}


void loop() {

  switch (status) {
  case GET:
    getStart(); // check for incoming information on h/w serial
    break;
  case READ:
    readData();
    break;
  case COMBINE:
    combineMessages();   // Add my part of the sentence to the buffer
    break;
  case ANNOUNCE:
    announce();
    break;
  case SEND:
    sendData(); // continuously send information to the next hop
    break;
  case DONE:
    done();// indicate task completed
    break;
  }

}


void getStart() {
  if (Serial.available() > 0) {
    char inChar = Serial.read(); // read a character
    if (inChar == '~') { // look for start byte, in this case 0x7E aka the tilde aka ~
      status= READ; // change to the next mode
    }
  }
}


void readData() {
  if (Serial.available() > 0) {
    char inChar = Serial.read(); // read a character
    if (inChar == '\n') { // if we've reached the end of the message
      status = COMBINE; // change to the next mode
    }
    else {
      buffer[idx] = inChar; // copy the incoming character into the buffer
      idx++; // increment to the next position in the receive string
    }
  }
}


void combineMessages() {
  strcat(buffer, " "); // add a space between each word in the message
  strcat(buffer, MESSAGE); // add your part of the message
  status = ANNOUNCE;
}


void announce() {
  ////////// THIS IS WHERE YOU PUT YOUR FANTASTIC ACTION ///////////////////
  blinkLED(LED_PIN,2,1000);// perform a fantastic action to indicate receipt
  /////////////////////////////////////////////////////////////////////////
  status = SEND;
}


void sendData() {
  for (int i=0; i<1000; i++) { // repeatedly sends the message onward
    softSerial.print("~"); // print the start byte
    for (int i=0; i<strlen(buffer); i++) { // step through the buffer...
      softSerial.print(buffer[i]); // ...printing each byte one at a time
    }
    softSerial.print("\n"); // print the stop byte
      blinkLED(LED_PIN, 1, 25);
    delay(100); // wait a moment between each send cycle
  }
  status = DONE;
}


void done() {
  blinkLED(LED_PIN, 1, 1000);
  // THIS IS WHERE YOU COULD PUT A RESET SWITCH TO START AGAIN
  // IN WHICH CASE SET STATUS BACK TO GET
  // if (RESET_SWTICH == LOW) {
  //   index = 0;
  //   clearbuffer();
  //   status = GET;
  // }
}


////////////////// UTILITIES //////////////////
// this function blinks the an LED light as many times as requested, at the requested blinking rate
void blinkLED(byte targetPin, int numBlinks, int blinkRate) {
  for (int i=0; i<numBlinks; i++) {
    digitalWrite(targetPin, HIGH);   // sets the LED on
    delay(blinkRate);                     // waits for blinkRate milliseconds
    digitalWrite(targetPin, LOW);    // sets the LED off
    delay(blinkRate);
  }
}

// clears the buffer when called
void clearBuffer() {
  for (int i=0; i<BUFFER_SIZE; i++) {
    buffer[i]=NULL;
  }
}